//------------------------------------------------------------------
#property copyright "mladen"
#property link      "www.forex-tsd.com"
#property version   "1.00"
//------------------------------------------------------------------
#property indicator_separate_window
#property indicator_buffers   7
#property indicator_plots     6
#property indicator_label1  "Band up 2"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrLimeGreen
#property indicator_label2  "Band up 1"
#property indicator_type2   DRAW_LINE
#property indicator_style2  STYLE_DOT
#property indicator_color2  clrLimeGreen
#property indicator_label3  "Middle"
#property indicator_type3   DRAW_LINE
#property indicator_style2  STYLE_DOT
#property indicator_color3  clrSilver
#property indicator_label4  "Band down 1"
#property indicator_type4   DRAW_LINE
#property indicator_style4  STYLE_DOT
#property indicator_color4  clrOrangeRed
#property indicator_label5  "Band down 2"
#property indicator_type5   DRAW_LINE
#property indicator_color5  clrOrangeRed
#property indicator_label6  "macd"
#property indicator_type6   DRAW_COLOR_LINE
#property indicator_width6  3
#property indicator_color6  clrSilver,clrGreen,clrLimeGreen,clrRed,clrOrangeRed

//
//
//
//
//

enum enPrices
{
   pr_close,      // Close
   pr_open,       // Open
   pr_high,       // High
   pr_low,        // Low
   pr_median,     // Median
   pr_typical,    // Typical
   pr_weighted,   // Weighted
   pr_average,    // Average (high+low+open+close)/4
   pr_medianb,    // Average median body (open+close)/2
   pr_tbiased,    // Trend biased price
   pr_tbiased2,   // Trend biased (extreme) price
   pr_haclose,    // Heiken ashi close
   pr_haopen ,    // Heiken ashi open
   pr_hahigh,     // Heiken ashi high
   pr_halow,      // Heiken ashi low
   pr_hamedian,   // Heiken ashi median
   pr_hatypical,  // Heiken ashi typical
   pr_haweighted, // Heiken ashi weighted
   pr_haaverage,  // Heiken ashi average
   pr_hamedianb,  // Heiken ashi median body
   pr_hatbiased,  // Heiken ashi trend biased price
   pr_hatbiased2  // Heiken ashi trend biased (extreme) price
};
enum stdMethods
{
   std_custSam, // Custom - with sample correction
   std_custNos  // Custom - without sample correction
};

input double      FastEma               = 12;          // Fast ema period
input double      SlowEma               = 26;          // Slow ema period
input enPrices    Price                 = pr_close;    // Price
input int         DeviationsLength      = 20;          // Deviations period
input double      DeviationsMultiplier1 = 1;           // First deviation bands multiplier 
input double      DeviationsMultiplier2 = 2;           // Second deviation bands multiplier 
input stdMethods  DeviationType         = std_custSam; // Deviation calculation type

double val[],valc[],levelup2[],levelup1[],levelmi[],leveldn1[],leveldn2[];

//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//

int OnInit()
{
   SetIndexBuffer(0,levelup2 ,INDICATOR_DATA);
   SetIndexBuffer(1,levelup1 ,INDICATOR_DATA);
   SetIndexBuffer(2,levelmi  ,INDICATOR_DATA);
   SetIndexBuffer(3,leveldn1 ,INDICATOR_DATA);
   SetIndexBuffer(4,leveldn2 ,INDICATOR_DATA);
   SetIndexBuffer(5,val      ,INDICATOR_DATA);
   SetIndexBuffer(6,valc     ,INDICATOR_COLOR_INDEX);

   //
   //
   //
   //
   //
   
      string add = (DeviationType==std_custNos) ? "without sample correction" : "with sample correction";
   IndicatorSetString(INDICATOR_SHORTNAME,"macd "+add+" deviation ("+(string)FastEma+","+(string)SlowEma+","+(string)DeviationsLength+","+(string)DeviationsMultiplier1+","+(string)DeviationsMultiplier2+")");
   return(0);
}

//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//

int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime& time[],
                const double& open[],
                const double& high[],
                const double& low[],
                const double& close[],
                const long& tick_volume[],
                const long& volume[],
                const int& spread[])
{
   if (Bars(_Symbol,_Period)<rates_total) return(-1);
      
   //
   //
   //
   //
   //
         
   for (int i=(int)MathMax(prev_calculated-1,0); i<rates_total; i++)
   {
      double price = getPrice(Price,open,close,high,low,i,rates_total);
      val[i] = iEma(price,FastEma,i,rates_total,0)-iEma(price,SlowEma,i,rates_total,1);
      levelmi[i] = 0; for (int k=0; k<DeviationsLength && (i-k)>=0; k++) levelmi[i] += val[i-k]; levelmi[i] /= DeviationsLength;
            double deviation = iDeviation(val[i],DeviationsLength,DeviationType==std_custSam,i,rates_total);
                   levelup1[i] = levelmi[i]+DeviationsMultiplier1*deviation;
                   levelup2[i] = levelmi[i]+DeviationsMultiplier2*deviation;
                   leveldn2[i] = levelmi[i]-DeviationsMultiplier2*deviation;
                   leveldn1[i] = levelmi[i]-DeviationsMultiplier1*deviation;
                   valc[i] = 0;
                   while (true) 
                   {
                        if (val[i]>levelup2[i]) { valc[i]=2; break; }
                        if (val[i]>levelup1[i]) { valc[i]=1; break; }
                        if (val[i]<leveldn2[i]) { valc[i]=4; break; }
                        if (val[i]<leveldn1[i]) { valc[i]=3; break; }
                                                             break;
                   }
   }
   return(rates_total);
}


//------------------------------------------------------------------
//                                                                  
//------------------------------------------------------------------
// 
//
//
//
//

double workDev[];
double iDeviation(double value, int length, bool isSample, int i, int bars)
{
   if (ArraySize(workDev)!=bars) ArrayResize(workDev,bars); workDev[i] = value;
                 
   //
   //
   //
   //
   //
   
      double oldMean   = value;
      double newMean   = value;
      double squares   = 0; int k;
      for (k=1; k<length && (i-k)>=0; k++)
      {
         newMean  = (workDev[i-k]-oldMean)/(k+1)+oldMean;
         squares += (workDev[i-k]-oldMean)*(workDev[i-k]-newMean);
         oldMean  = newMean;
      }
      return(MathSqrt(squares/MathMax(k-isSample,1)));
}

//
//
//
//
//

double workEma[][2];
double iEma(double price, double period, int r, int bars, int instanceNo=0)
{
   if (ArrayRange(workEma,0)!= bars) ArrayResize(workEma,bars);

   workEma[r][instanceNo] = price;
   if (r>0 && period>1)
          workEma[r][instanceNo] = workEma[r-1][instanceNo]+(2.0 / (1.0+period))*(price-workEma[r-1][instanceNo]);
   return(workEma[r][instanceNo]);
}

//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//
//

double workHa[][4];
double getPrice(int tprice, const double& open[], const double& close[], const double& high[], const double& low[], int i, int _tbars, int instanceNo=0)
{
  if (tprice>=pr_haclose)
   {
      if (ArrayRange(workHa,0)!= _tbars) ArrayResize(workHa,_tbars); instanceNo*=4;
         
         //
         //
         //
         //
         //
         
         double haOpen;
         if (i>0)
                haOpen  = (workHa[i-1][instanceNo+2] + workHa[i-1][instanceNo+3])/2.0;
         else   haOpen  = (open[i]+close[i])/2;
         double haClose = (open[i] + high[i] + low[i] + close[i]) / 4.0;
         double haHigh  = MathMax(high[i], MathMax(haOpen,haClose));
         double haLow   = MathMin(low[i] , MathMin(haOpen,haClose));

         if(haOpen  <haClose) { workHa[i][instanceNo+0] = haLow;  workHa[i][instanceNo+1] = haHigh; } 
         else                 { workHa[i][instanceNo+0] = haHigh; workHa[i][instanceNo+1] = haLow;  } 
                                workHa[i][instanceNo+2] = haOpen;
                                workHa[i][instanceNo+3] = haClose;
         //
         //
         //
         //
         //
         
         switch (tprice)
         {
            case pr_haclose:     return(haClose);
            case pr_haopen:      return(haOpen);
            case pr_hahigh:      return(haHigh);
            case pr_halow:       return(haLow);
            case pr_hamedian:    return((haHigh+haLow)/2.0);
            case pr_hamedianb:   return((haOpen+haClose)/2.0);
            case pr_hatypical:   return((haHigh+haLow+haClose)/3.0);
            case pr_haweighted:  return((haHigh+haLow+haClose+haClose)/4.0);
            case pr_haaverage:   return((haHigh+haLow+haClose+haOpen)/4.0);
            case pr_hatbiased:
               if (haClose>haOpen)
                     return((haHigh+haClose)/2.0);
               else  return((haLow+haClose)/2.0);        
            case pr_hatbiased2:
               if (haClose>haOpen)  return(haHigh);
               if (haClose<haOpen)  return(haLow);
                                    return(haClose);        
         }
   }
   
   //
   //
   //
   //
   //
   
   switch (tprice)
   {
      case pr_close:     return(close[i]);
      case pr_open:      return(open[i]);
      case pr_high:      return(high[i]);
      case pr_low:       return(low[i]);
      case pr_median:    return((high[i]+low[i])/2.0);
      case pr_medianb:   return((open[i]+close[i])/2.0);
      case pr_typical:   return((high[i]+low[i]+close[i])/3.0);
      case pr_weighted:  return((high[i]+low[i]+close[i]+close[i])/4.0);
      case pr_average:   return((high[i]+low[i]+close[i]+open[i])/4.0);
      case pr_tbiased:   
               if (close[i]>open[i])
                     return((high[i]+close[i])/2.0);
               else  return((low[i]+close[i])/2.0);        
      case pr_tbiased2:   
               if (close[i]>open[i]) return(high[i]);
               if (close[i]<open[i]) return(low[i]);
                                     return(close[i]);        
   }
   return(0);
}