//+------------------------------------------------------------------+
//|                                                  Customstoch.mq4 |
//|                      Copyright © 2009, MetaQuotes Software Corp. |
//|                                        http://www.metaquotes.net |
//+------------------------------------------------------------------+
#property copyright "Anakin"
#property link      ""
 
#property indicator_separate_window
#property indicator_minimum 0
#property indicator_maximum 100
#property indicator_buffers 2
#property indicator_color1 Aqua
#property indicator_color2 Violet
#property indicator_width1 1
#property indicator_width2 1

//---- input parameters
extern int KPeriod=14;
extern int DPeriod=3;
extern int Slowing=3;
//---- buffers
double MainBuffer[];
double SignalBuffer[];
double HighesBuffer[];
double LowesBuffer[];
//----
int draw_begin1 = 0;
int draw_begin2 = 0;
int overBought  = 80;
int overSold    = 20;

extern string Sound1 = "alert.wav";

//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
   string short_name;
//---- 2 additional buffers are used for counting.
   IndicatorBuffers(4);
   SetIndexBuffer(2, HighesBuffer);
   SetIndexBuffer(3, LowesBuffer);
//---- indicator lines
   SetIndexStyle(0,DRAW_LINE);
   SetIndexBuffer(0, MainBuffer);
   SetIndexStyle(1,DRAW_LINE);
   SetIndexBuffer(1, SignalBuffer);
//---- name for DataWindow and indicator subwindow label
   short_name="SG SlowStoch("+KPeriod+","+DPeriod+","+Slowing+")";
   IndicatorShortName(short_name);
   SetIndexLabel(0,short_name);
   SetIndexLabel(1,"Signal");
//----
   draw_begin1=KPeriod+Slowing;
   draw_begin2=draw_begin1+DPeriod;
   SetIndexDrawBegin(0,draw_begin1);
   SetIndexDrawBegin(1,draw_begin2);
//----
   //levels and zones
   SetLevelValue(0,overSold);
   SetLevelValue(1,overBought);
   SetLevelStyle(STYLE_SOLID,2,Red);
   
   return(0);
  }
//+------------------------------------------------------------------+
//| Stochastic oscillator                                            |
//+------------------------------------------------------------------+
int start()
  {
   int    i,k;
   int    counted_bars=IndicatorCounted();
   double price;
//----
   if(Bars<=draw_begin2) return(0);
//---- initial zero
   if(counted_bars<1)
     {
      for(i=1;i<=draw_begin1;i++) MainBuffer[Bars-i]=0;
      for(i=1;i<=draw_begin2;i++) SignalBuffer[Bars-i]=0;
     }
//---- minimums counting
   i=Bars-KPeriod;
   if(counted_bars>KPeriod) i=Bars-counted_bars-1;
   while(i>=0)
     {
      double min=1000000;
      k=i+KPeriod-1;
      while(k>=i)
        {
         price=Low[k];
         if(min>price) min=price;
         k--;
        }
      LowesBuffer[i]=min;
      i--;
     }
//---- maximums counting
   i=Bars-KPeriod;
   if(counted_bars>KPeriod) i=Bars-counted_bars-1;
   while(i>=0)
     {
      double max=-1000000;
      k=i+KPeriod-1;
      while(k>=i)
        {
         price=High[k];
         if(max<price) max=price;
         k--;
        }
      HighesBuffer[i]=max;
      i--;
     }
//---- %K line
   i=Bars-draw_begin1;
   if(counted_bars>draw_begin1) i=Bars-counted_bars-1;
   while(i>=0)
     {
      double sumlow=0.0;
      double sumhigh=0.0;
      for(k=(i+Slowing-1);k>=i;k--)
        {
         sumlow+=Close[k]-LowesBuffer[k];
         sumhigh+=HighesBuffer[k]-LowesBuffer[k];
        }
      if(sumhigh==0.0) MainBuffer[i]=100.0;
      else MainBuffer[i]=sumlow/sumhigh*100;
      i--;
     }
//---- last counted bar will be recounted
   if(counted_bars>0) counted_bars--;
   int limit=Bars-counted_bars;
//---- signal line is simple movimg average
   for(i=0; i<limit; i++){
      SignalBuffer[i]=iMAOnArray(MainBuffer,Bars,DPeriod,0,MODE_SMA,i);
      
      //ALERTING FEATURE
      // el i=0 es que que esta dibujado
      if (i == 0){
         //Print ("Time: if ("+TimeCurrent()+" > "+StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" 8:00")+") && ("+TimeCurrent()+" < "+StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" 19:00")+")");
         //IF is on the right time. CHECK IT WORKS
         if(TimeCurrent()> StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" 6:30") && TimeCurrent() < StrToTime(TimeToStr(TimeCurrent(), TIME_DATE)+" 19:00")){
            Print("SG SLOWSTOCH RIGHT TIME!!");
            /////DOWN TREND TRADE //////
            /////IF GLOBAR VARS == -1
            if ( GlobalVariableGet(Symbol()+"_M5_macd_trend") == GlobalVariableGet(Symbol()+"_M5_sar_trend") && GlobalVariableGet(Symbol()+"_M5_sar_trend") == -1){
               if ( (MainBuffer[i] > overBought) && (SignalBuffer[i] > overBought) ){
                  Print("SG SLOWSTOCH OVERBOUGHT ZONE("+MainBuffer[i]+","+SignalBuffer[i]+"); "+i);
                  PlaySound(Sound1);
               }
            }
            
            /////UP TREND TRADE //////
            /////IF GLOBAR VARS == 1            
            if ( GlobalVariableGet(Symbol()+"_M5_macd_trend") == GlobalVariableGet(Symbol()+"_M5_sar_trend") && GlobalVariableGet(Symbol()+"_M5_sar_trend") == 1){
               if ( (MainBuffer[i] < overSold) && (SignalBuffer[i] < overSold) ){
                  Print("SG SLOWSTOCH OVERSOLD ZONE("+MainBuffer[i]+","+SignalBuffer[i]+"); "+i);
                  PlaySound(Sound1);
               }
            }
         }
      }
      //END OF ALERTING FEATURE
   }
//----
   return(0);
  }
//+------------------------------------------------------------------+