//+------------------------------------------------------------------+
//|                                                  STO_CCI_RSI.mq4 |                                   
//+------------------------------------------------------------------+

#property indicator_separate_window
#property indicator_buffers 4
#property indicator_color1 Red
#property indicator_color2 Green
#property indicator_color3 Yellow
#property indicator_color4 Red
#property indicator_level1 0
#property indicator_level2 100
#property indicator_level3 -100

#property indicator_levelstyle STYLE_DOT
#property indicator_levelcolor DimGray

//
//
//
//
//

extern string TimeFrame       = "Current time frame";
extern string ForSymbol       = "";                  // Symbol to use (leave empty for current symbol)
extern int    RsiPer          =  9;
extern int    StochPer        =   14;
extern int    CCIPer          =   20;
extern double Hot             = 0.4;
extern int    Smoothing       =   4;
extern bool   Interpolate     = true;
extern bool   alertsOn        = false;
extern bool   alertsOnCurrent = FALSE;
extern bool   alertsMessage   = true;
extern bool   alertsSound     = false;
extern bool   alertsEmail     = false;

double Signal1[],Signal2[],upX[],downX[],trend[];

//
//
//
//
//

string indicatorFileName;
bool   returnBars;
bool   calculateValue;
int    timeFrame;

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

int init()
{
   for (int i=0; i<indicator_buffers; i++) SetIndexStyle(i,DRAW_LINE);
	string FileName;
	IndicatorBuffers(5);
      SetIndexBuffer(0,Signal1);
      SetIndexBuffer(1,Signal2);
      SetIndexBuffer(2,upX);   SetIndexStyle(2,DRAW_ARROW); SetIndexArrow(2,159);
      SetIndexBuffer(3,downX); SetIndexStyle(3,DRAW_ARROW);	SetIndexArrow(3,159);
      SetIndexBuffer(4,trend);

      for (i=0; i < 4; i++) SetIndexDrawBegin(i,RsiPer+StochPer+CCIPer+Hot+Smoothing);

      //
      //
      //
      //
      //
      
         indicatorFileName = WindowExpertName();
         returnBars        = (TimeFrame=="returnBars");     if (returnBars)     return(0);
         calculateValue    = (TimeFrame=="calculateValue"); if (calculateValue) return(0);
         timeFrame         = stringToTimeFrame(TimeFrame);
         ForSymbol         = (ForSymbol=="") ? _Symbol : ForSymbol; 

      //
      //
      //
      //
      //
      
   IndicatorShortName(timeFrameToString(timeFrame)+" "+ForSymbol+" STO CCI RSI ("+RsiPer+","+StochPer+","+CCIPer+","+DoubleToStr(Hot,2)+","+Smoothing+")"); 
	return(0);
}

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

int start()
{
   int i,n,limit,counted_bars=IndicatorCounted();

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-1);
         if (returnBars) { Signal1[0] = limit+1; return(0); }
	
      	double Sm = Smoothing;
         	if (Sm<2) Sm=2;
               double sk  = 2.0 / (Sm + 1.0);
               double sk2 = 2.0 / (Sm * 0.8 + 1.0);

   //
   //
   //
   //
   //
   
   if (calculateValue || (ForSymbol == Symbol() && timeFrame == Period()))
   {
      for(i=limit; i>=0; i--)
      {
         double rsi   =  iRSI(ForSymbol,0,RsiPer,PRICE_CLOSE,i);
         double maxrsi = rsi;
         double minrsi = rsi;

                  for (int k=1; k<=StochPer; k++)
                  {
                     double trsi   = iRSI(ForSymbol,0,RsiPer,PRICE_CLOSE,i+k);
                            maxrsi = MathMax(maxrsi,trsi);
                            minrsi = MathMin(minrsi,trsi);
                  }
                  if (maxrsi==minrsi)
         		       double storsi = 0;
                  else  	  storsi = ((rsi-minrsi)/(maxrsi-minrsi)*200-100);
         
         double SCR = Hot*iCCI(ForSymbol,0,CCIPer,PRICE_TYPICAL,i)+(1-Hot)*storsi;

         //
         //
         //
         //
         //
      
   		Signal1[i] = sk *SCR         +(1-sk )*Signal1[i+1];
         Signal2[i] = sk2*Signal1[i+1]+(1-sk2)*Signal2[i+1];
         upX[i]     = EMPTY_VALUE;
         downX[i]   = EMPTY_VALUE;
         trend[i]   = trend[i+1];
		
         if (Signal1[i]>Signal2[i]) trend[i] =  1;
         if (Signal1[i]<Signal2[i]) trend[i] = -1;
         if (trend[i] != trend[i+1])
               if (trend[i]==1) 
                     upX[i]   = Signal2[i]-15;
               else  downX[i] = Signal2[i]+15;
      }
      manageAlerts();
      return(0);
   }
   
   //
   //
   //
   //
   //
   
   limit = MathMax(limit,MathMin(Bars-1,iCustom(ForSymbol,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
   for (i=limit; i>=0; i--)
   {
      int y = iBarShift(ForSymbol,timeFrame,Time[i]);
         Signal1[i] = iCustom(ForSymbol,timeFrame,indicatorFileName,"calculateValue","",RsiPer,StochPer,CCIPer,Hot,Smoothing,0,y);
         Signal2[i] = iCustom(ForSymbol,timeFrame,indicatorFileName,"calculateValue","",RsiPer,StochPer,CCIPer,Hot,Smoothing,1,y);
         trend[i]   = iCustom(ForSymbol,timeFrame,indicatorFileName,"calculateValue","",RsiPer,StochPer,CCIPer,Hot,Smoothing,4,y);
         upX[i]     = EMPTY_VALUE;
         downX[i]   = EMPTY_VALUE;

            //
            //
            //
            //
            //
            
            if (trend[i]!=trend[i+1])
                  if (trend[i]==1) 
                        upX[i]   = Signal2[i]-15;
                  else  downX[i] = Signal2[i]+15;
            if (!Interpolate || y==iBarShift(ForSymbol,timeFrame,Time[i-1])) continue;

            //
            //
            //
            //
            //

            datetime time = iTime(ForSymbol,timeFrame,y);
               for(n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
               for(k = 1; k < n; k++)
               {
                  Signal1[i+k] = Signal1[i] + (Signal1[i+n] - Signal1[i])*k/n;
                  Signal2[i+k] = Signal2[i] + (Signal2[i+n] - Signal2[i])*k/n;
               }                  
   }  
   
   //
   //
   //
   //
   //
   
   manageAlerts();
   return(0);
}


//+-------------------------------------------------------------------
//|                                                                  
//+-------------------------------------------------------------------
//
//
//
//
//

void manageAlerts()
{
   if (!calculateValue && alertsOn)
   {
      if (alertsOnCurrent)
           int whichBar = 0;
      else     whichBar = 1; whichBar = iBarShift(ForSymbol,0,iTime(NULL,timeFrame,whichBar));
      if (trend[whichBar] != trend[whichBar+1])
      {
         if (trend[whichBar] ==  1) doAlert(whichBar,"up");
         if (trend[whichBar] == -1) doAlert(whichBar,"down");
      }
   }
}

//
//
//
//
//

void doAlert(int forBar, string doWhat)
{
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   
   if (previousAlert != doWhat || previousTime != Time[forBar]) {
       previousAlert  = doWhat;
       previousTime   = Time[forBar];

       //
       //
       //
       //
       //

       message =  StringConcatenate(Symbol()," STO CCI Rsi - at ",TimeToStr(TimeLocal(),TIME_SECONDS)," trend changed to ",doWhat);
          if (alertsMessage) Alert(message);
          if (alertsEmail)   SendMail(StringConcatenate(Symbol(),"Sto CCI Rsi"),message);
          if (alertsSound)   PlaySound("alert2.wav");
   }
}


//+-------------------------------------------------------------------
//|                                                                  
//+-------------------------------------------------------------------
//
//
//
//
//

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = stringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string stringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int tchar = StringGetChar(s, length);
         if((tchar > 96 && tchar < 123) || (tchar > 223 && tchar < 256))
                     s = StringSetChar(s, length, tchar - 32);
         else if(tchar > -33 && tchar < 0)
                     s = StringSetChar(s, length, tchar + 224);
   }
   return(s);
}