//+------------------------------------------------------------------+
//|                                                dynamic zone MACD |
//|                                                           mladen |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_separate_window
#property indicator_buffers 4
#property indicator_color1  DeepSkyBlue
#property indicator_color2  Gold
#property indicator_color3  LimeGreen
#property indicator_color4  Red
#property indicator_width1  2
#property indicator_style2  STYLE_DOT

//
//
//
//
//

extern int    MacdFast               = 12;
extern int    MacdSlow               = 26;
extern int    MacdSignal             =  9;
extern int    MacdSignalMode         = MODE_EMA;
extern int    MacdPrice              = PRICE_CLOSE;
extern int    DzLookBackBars         = 70;
extern double DzStartBuyProbability  = 0.12;
extern double DzStartSellProbability = 0.12;

//
//
//
//
//

double macd[];
double macs[];
double bli[];
double sli[];

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   SetIndexBuffer(0,macd); SetIndexLabel(0,"MACD");
   SetIndexBuffer(1,macs); SetIndexLabel(1,"MACD signal");
   SetIndexBuffer(2,bli);
   SetIndexBuffer(3,sli);

   //
   //
   //
   //
   //
   
   string PriceType;
      switch(MacdPrice)
      {
         case PRICE_CLOSE:    PriceType = "Close";    break;  // 0
         case PRICE_OPEN:     PriceType = "Open";     break;  // 1
         case PRICE_HIGH:     PriceType = "High";     break;  // 2
         case PRICE_LOW:      PriceType = "Low";      break;  // 3
         case PRICE_MEDIAN:   PriceType = "Median";   break;  // 4
         case PRICE_TYPICAL:  PriceType = "Typical";  break;  // 5
         case PRICE_WEIGHTED: PriceType = "Weighted"; break;  // 6
      }      

   //
   //
   //
   //
   //

   MacdFast = MathMax(MacdFast ,1);
   MacdSlow = MathMax(MacdSlow ,1);
   IndicatorShortName ("Dynamic zone MACD ("+MacdFast+","+MacdSlow+","+MacdSignal+","+PriceType+","+DzLookBackBars+","+DoubleToStr(DzStartBuyProbability,3)+","+DoubleToStr(DzStartSellProbability,3)+")");
   return(0);
}
int deinit()
{
   return(0);
}

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int start()
{
   int counted_bars=IndicatorCounted();
   int i,pipMultiplier,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-1);
         if (Digits == 3 || Digits == 5)
               pipMultiplier = 10;
         else  pipMultiplier = 1;                

   //
   //
   //
   //
   //
   //

      for(i=limit; i >= 0; i--) macd[i] = iMACD(NULL,0,MacdFast,MacdSlow,1,MacdPrice,MODE_MAIN,i)/Point/pipMultiplier;
      for(i=limit; i >= 0; i--)
      {
         macs[i] = iMAOnArray(macd,0,MacdSignal,0,MacdSignalMode,i);
         bli[i]  = dzBuy (i,macd,DzStartBuyProbability,  DzLookBackBars);
         sli[i]  = dzSell(i,macd,DzStartSellProbability, DzLookBackBars);
      }
   return(0);
}



//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

double dzBuy(int i, double& array[], double initValue, int lookBackBars)
{
   double left  = -10000;
   double right =  10000;
   
   if ((Bars-i)<lookBackBars) return(EMPTY_VALUE);
   
   //
   //
   //
   //
   //

   double eps      = 0.001;
   double yval     = (left+right)/2.0;
	double delta    = yval-left;
	int    maxSteps = 0;
	
		while (delta>0.005 && maxSteps<50)
		{
			maxSteps++;
   	      double count = 0;
			   for (int k=0; k<lookBackBars;k++) if (array[i+k]<yval) count++;
	
				double prob = count/lookBackBars;
               if (prob>(initValue+eps))
               {
                  right = yval;
                  yval  = (yval+left)/2.0;
               }                  
               if (prob<(initValue-eps))
               {
                  left = yval;
                  yval = (yval+right)/2.0;
               }
               if (prob<(initValue+eps) && prob>(initValue-eps))
               {
                  right = yval;
                  yval  = (yval+left)/2.0;
               }
               delta=yval-left;
      }               
      return(yval);   
}

//
//
//
//
//

double dzSell(int i, double& array[], double initValue, int lookBackBars)
{
   double left  = -10000;
   double right =  10000;
   
   if ((Bars-i)<lookBackBars) return(EMPTY_VALUE);
   
   //
   //
   //
   //
   //

   double eps      = 0.001;
   double yval     = (left+right)/2.0;
	double delta    = yval-left;
	int    maxSteps = 0;
	
		while (delta>0.005 && maxSteps<50)
		{
			maxSteps++;
   	      double count = 0;
			   for (int k=0; k<lookBackBars;k++) if (array[i+k]>yval) count++;
	
				double prob = count/lookBackBars;
               if (prob>(initValue+eps))
               {
                  left = yval;
                  yval = (yval+right)/2.0;
               }                  
               if (prob<(initValue-eps))
               {
                  right = yval;
                  yval  = (yval+left)/2.0;
               }
               if (prob<(initValue+eps) && prob>(initValue-eps))
               {
                  left = yval;
                  yval = (yval+right)/2.0;
               }
               delta=yval-left;
      }               
      return(yval);   
}