//+------------------------------------------------------------------+
//|                                  Copyright © 2011, John Wustrack |
//|                                        john_wustrack@hotmail.com |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2011, John Wustrack"
#property link      "john_wustrack@hotmail.com"

#property indicator_chart_window

#property indicator_buffers 2


#define MR_NONE 0
#define MR_LONG 1
#define MR_SHORT 2
#define MR_RANGE 3
#define MR_CTLONG 4
#define MR_CTSHORT 5
#define MR_NOTAPPLICABLE 6

#define DFT_MARKETREAD 3

#define TLE_MODEOPEN 1
#define TLE_MODECLOSE 9

#define OPEN_BUY 1
#define OPEN_SELL 2
#define OPEN_BUYSTOP 3
#define OPEN_BUYLIMIT 4
#define OPEN_SELLSTOP 5
#define OPEN_SELLLIMIT 6

#define CLOSE_ORDER 9

#define DFT_RETURN -1

extern int MarketRead;
extern int TLEMode;
extern int BasketType;

// User Definitions for other indicators etc.
#define VQSig_TF 15
#define VQSig_Period 7
#define VQSig_Method MODE_LWMA
#define VQSig_Smoothing 1
#define VQSig_Filter 5

#define VQTrnd_TF 240
#define VQTrnd_Period 7
#define VQTrnd_Method MODE_LWMA
#define VQTrnd_Smoothing 1
#define VQTrnd_Filter 5



double CB_Action[];
double CB_Price[];

datetime LastAlert;
datetime LastBar;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
//----
   IndicatorBuffers(2);
   SetIndexBuffer(0,CB_Action);
   SetIndexBuffer(1,CB_Price);
   IndicatorDigits(Digits);
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
//----
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
  {
//----
   // Reset any close request on subsequent entry
   if (CB_Action[0] == CLOSE_ORDER)
      {
      CB_Action[0] = DFT_RETURN;
      // If an order cannot be opened on the same bar one is closed - comment out this line 
      LastBar = 0;
      }

   // Do nothing if the market read is NONE
   if (MarketRead == MR_NONE) return(0);
      
   // If the mode is not open or close - do nothing
   if (TLEMode != TLE_MODEOPEN && TLEMode != TLE_MODECLOSE) return(0);
   
   // If the timeframe is greater than the minimim - do nothing
   if (Period() > VQSig_TF) return(0);
   
   // Perform the trade logic
   if (TLEMode == TLE_MODEOPEN) Check_For_Open();
   if (TLEMode == TLE_MODECLOSE) Check_For_Close();
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Check for open of new trade                                      |
//+------------------------------------------------------------------+
int Check_For_Open()
  {
//----
         
   // Decide if the routine is to be run every tick
   // if so, comment out the next if statement
   if (Time[0] == LastBar) return(0);  // Once per bar 
   
   LastBar = Time[0];
   
   if (Time[0] == LastAlert) return(0);

   // Reset the communication buffers
   CB_Action[0] = DFT_RETURN;
   CB_Price[0] = DFT_RETURN;
   
   // Set the default market read if the market read is not applicable
   if (MarketRead == MR_NOTAPPLICABLE) MarketRead = DFT_MARKETREAD;
   
/*

the rest of the code in this routine is the user defined code for the TLE

*/

   // Get the VQ variables for signal & trend
   // For signal we used closed bars only, for trend we take the open bar 
   double ld_VQ.Sig.Cur = iCustom(NULL,0,"VQzz",VQSig_TF,VQSig_Period,VQSig_Method,VQSig_Smoothing,VQSig_Filter,2,1);
//   double ld_VQ.Sig.Prv = iCustom(NULL,0,"VQzz",VQSig_TF,VQSig_Period,VQSig_Method,VQSig_Smoothing,VQSig_Filter,2,2);
      
   double ld_VQ.Trnd.Cur = iCustom(NULL,0,"VQzz",VQTrnd_TF,VQTrnd_Period,VQTrnd_Method,VQTrnd_Smoothing,VQTrnd_Filter,2,0);
//   double ld_VQ.Trnd.Prv = iCustom(NULL,0,"VQzz",VQTrnd_TF,VQTrnd_Period,VQTrnd_Method,VQTrnd_Smoothing,VQTrnd_Filter,2,1);

   bool lb_Long, lb_Short;
   
   // Check for signals based on market read
   switch (MarketRead)
      {
      // Long
      case MR_LONG:     if (ld_VQ.Sig.Cur > 0)
                           lb_Long = true;
                        break;
      // Short 
      case MR_SHORT:    if (ld_VQ.Sig.Cur < 0)
                           lb_Short = true;
                        break;
      // Range 
      case MR_RANGE:    if ((ld_VQ.Sig.Cur > 0) &&
                           (ld_VQ.Trnd.Cur > 0))
                           lb_Long = true;
                            
                        if ((ld_VQ.Sig.Cur < 0) &&
                           (ld_VQ.Trnd.Cur < 0))
                           lb_Short = true;
                        break;
      // CT Long 
      case MR_CTLONG:   if (ld_VQ.Sig.Cur > 0)
                           lb_Long = true;
                        if ((ld_VQ.Sig.Cur < 0) &&
                           (ld_VQ.Trnd.Cur < 0))
                           lb_Short = true;
                        break;
      // CT Short 
      case MR_CTSHORT:  if (ld_VQ.Sig.Cur < 0)
                           lb_Short = true;
                        if ((ld_VQ.Sig.Cur > 0) &&
                           (ld_VQ.Trnd.Cur > 0))
                           lb_Long = true;
                        break;
      }
      
   
   // Send any alerts necessary
   if (lb_Short)
      {
      Alert("Possible SHORT opportunity at ",TimeToStr(Time[0],TIME_DATE|TIME_MINUTES));
      LastAlert = Time[0];
      CB_Action[0] = OPEN_SELL;
      CB_Price[0] = 0;
      }
   
          
   if (lb_Long)
      {
      Alert("Possible LONG opportunity at ",TimeToStr(Time[0],TIME_DATE|TIME_MINUTES));
      LastAlert = Time[0];
      CB_Action[0] = OPEN_BUY;
      CB_Price[0] = 0;
      }
   

//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Check for close of a trade                                       |
//+------------------------------------------------------------------+
int Check_For_Close()
  {
//----

   if (BasketType != OPEN_BUY && BasketType != OPEN_SELL) return(0);

   // Decide if the routine is to be run every tick
   // if so, comment out the next if statement
   if (Time[0] == LastBar) return(0);  // Once per bar 
   
   LastBar = Time[0];

//   if (Time[0] == LastAlert) return(0);  

   // Reset the communication buffers
   CB_Action[0] = DFT_RETURN;

/*

the rest of the code in this routine is the user defined code for the TLE

*/
   double ld_VQ.Sig.Cur = iCustom(NULL,0,"VQzz",VQSig_TF,VQSig_Period,VQSig_Method,VQSig_Smoothing,VQSig_Filter,2,1);
//   double ld_VQ.Sig.Prv = iCustom(NULL,0,"VQzz",VQSig_TF,VQSig_Period,VQSig_Method,VQSig_Smoothing,VQSig_Filter,2,2);

   // If the basket is a buy and VQ is now short
   if (BasketType == OPEN_BUY && ld_VQ.Sig.Cur < 0)
      {
      Alert("Close of long at ",TimeToStr(Time[0],TIME_DATE|TIME_MINUTES));
      LastAlert = Time[0];
      CB_Action[0] = CLOSE_ORDER;
      }
      
   // If the basket is a sell and VQ is now long
   if (BasketType == OPEN_SELL && ld_VQ.Sig.Cur > 0)
      {
      Alert("Close of short at ",TimeToStr(Time[0],TIME_DATE|TIME_MINUTES));
      LastAlert = Time[0];
      CB_Action[0] = CLOSE_ORDER;
      }
      
   // We don't want to send any actions UNLESS the market read is range
//   if (MarketRead != MR_RANGE)
//      CB_Action[0] = DFT_RETURN;
      
//----
   return(0);
  }
//+------------------------------------------------------------------+